AANTALLEN.ALS-voorbeelden in Excel: tellen met meerdere voorwaarden, ook tussen twee waarden

Wat doet AANTALLEN.ALS in Excel?

AANTALLEN.ALS telt de rijen die aan al je voorwaarden tegelijk voldoen. Waar AANTAL.ALS één vraag stelt, stelt AANTALLEN.ALS er zoveel als je nodig hebt: is het kleding, én kostte het meer dan 5 euro? =AANTALLEN.ALS(B2:B16;"Kleding";C2:C16;">5") geeft 3, want drie stuks kleding kostten meer dan 5 euro. In een Engelstalige Excel heet de functie COUNTIFS.

Alle voorbeelden rekenen op een week verkopen van Kringwinkel Tweede Kans in Gent, de vierde klant in onze Excel-cursus. Wil je de functie stap voor stap leren, volg dan de les over meerdere voorwaarden. Tel je nog maar met één voorwaarde, dan vind je in de voorbeelden van AANTAL.ALS alle soorten criteria. Hier gaat het om wat er verandert zodra er een tweede voorwaarde bij komt.

Hoe schrijf je een AANTALLEN.ALS-formule?

Met paren: telkens een bereik en het criterium dat bij dat bereik hoort. Het eerste paar is verplicht, en je mag tot 127 paren gebruiken (Microsoft). Er is geen apart bereik om te tellen, zoals bij SOMMEN.ALS het optelbereik: de functie telt rijen.

=AANTALLEN.ALS(criteriabereik1;criterium1;[criteriabereik2;criterium2];…)

In een Engelstalige Excel met Britse of Amerikaanse instellingen schrijf je =COUNTIFS(B2:B16,"Kleding",C2:C16,">5"). Alleen de functienaam en het scheidingsteken veranderen.

Hoe tel je met twee voorwaarden?

Coördinator Yasmina van Tweede Kans wil weten hoeveel dure kleding er de deur uit ging. Dit is het hele blad, met alle vijftien verkopen. In G2 staat een prijsgrens van 10 euro, waar we straks naar verwijzen.

=AANTALLEN.ALS(B2:B16;"Kleding";C2:C16;">5")

De formule geeft 3. Excel loopt de rijen af en test op elke rij beide voorwaarden. Kleding staat zes keer op het blad, maar alleen Jas groen, Jasje kind en Jas zwart kosten meer dan 5 euro. De radio van 15 euro valt af op de categorie, de T-shirts op de prijs. Dat de voorwaarden in verschillende kolommen staan, is geen probleem: de functie kijkt telkens naar dezelfde rij.

Nu jij. De oefening draait op het echte blad van Tweede Kans, en je typt de formule zoals in Excel.

Je formule rekende in je eigen browser, op een echte rekenmotor. Daarna rekenen we ze nog eens op een verborgen versie van het blad, met andere prijzen en vrijwilligers. Wie gewoon 3 intypt, valt daar door de mand.

Hoe tel je tussen twee waarden met AANTALLEN.ALS?

Gebruik dezelfde kolom twee keer, met een ondergrens en een bovengrens. Dat is het voorbeeld waarvoor de meeste mensen deze functie zoeken, want AANTAL.ALS kan het niet in één keer. Excel test beide voorwaarden op dezelfde cel, en alleen wat tussen de grenzen ligt, telt mee. Probeer het hier zelf.

Voor een periode werkt het op dezelfde manier, want een datum is voor Excel een getal. Stond er in kolom D een echte datum, dan telde =AANTALLEN.ALS(D2:D16;">="&DATUM(2026;11;1);D2:D16;"<"&DATUM(2026;12;1)) de verkopen van heel november. Hoe dat werkt met tijdstippen op de laatste dag, lees je bij SOMMEN.ALS met een periode.

Welke criteria kun je combineren?

Alle criteria die je kent van de les over criteria: tekst, getallen, vergelijkingen, jokertekens en verwijzingen naar een cel, ook door elkaar. Microsoft noemt dezelfde jokertekens als bij AANTAL.ALS (Microsoft). Op het blad van Tweede Kans ziet dat er zo uit:

Vooral het criterium met een cel is de moeite waard. Zet je de grens in G2 en verwijs je ernaar met ">"&G2, dan past Yasmina de grens aan zonder de formule te openen. Tussen de aanhalingstekens staat alleen het teken, de verwijzing staat erbuiten.

Hoe maak je een overzicht per categorie en persoon?

Met één formule die je doortrekt, dankzij gemengde verwijzingen. Zet de categorieën onder elkaar in kolom K en de namen naast elkaar in rij 1, en schrijf in L2:

=AANTALLEN.ALS($B$2:$B$16;$K2;$E$2:$E$16;L$1)

Trek je die formule naar rechts en naar beneden, dan blijven de bereiken staan, schuift $K2 mee met de rij en L$1 mee met de kolom. Zo krijg je een kruistabel:

Alles samen geeft dat 15, net zoveel als er rijen op het blad staan. Dat is meteen een handige controle: wijkt het totaal af, dan staat er ergens een categorie of naam met een tikfout.

Kan AANTALLEN.ALS werken met OF?

Niet met gewone criteria: alle voorwaarden moeten tegelijk kloppen. Daarom geeft =AANTALLEN.ALS(B2:B16;"Kleding";B2:B16;"Boeken") 0. Geen enkele cel is kleding én boeken tegelijk. Voor het ene of het andere tel je twee formules op: =AANTALLEN.ALS(B2:B16;"Kleding")+AANTALLEN.ALS(B2:B16;"Boeken") geeft 8, zes stuks kleding en twee boeken.

Dat optellen klopt omdat een rij maar één categorie heeft. Vraag je naar de kleding of alles van Sofie, dan kan één rij aan beide voldoen. Zes stuks kleding plus vijf verkopen van Sofie is 11, terwijl het er 8 zijn: de drie stuks kleding van Sofie staan dubbel in de som. Trek die er dus weer af, met een derde formule die beide voorwaarden samen test.

Waarom werkt mijn AANTALLEN.ALS niet?

De meeste fouten geven geen melding, maar een te lage telling. Controleer eerst of je voorwaarden samen kunnen kloppen, en werk dan dit lijstje af.

Je krijgt 0 terwijl er rijen zijn

Dat zijn vaak de spaties. Een spatie achteraan in een cel zie je niet, maar "Kleding" vindt die cel dan niet meer. Microsoft noemt spaties vooraan of achteraan als oorzaak van onverwachte uitkomsten (Microsoft). Ook ">G2" geeft 0, omdat Excel dan naar de letters G2 zoekt in plaats van naar de waarde in die cel.

De formule geeft #WAARDE!

Dan zijn de bereiken meestal niet even groot. Elk extra bereik moet evenveel rijen en kolommen hebben als het eerste (Microsoft). Ze hoeven niet naast elkaar te staan, maar ze moeten wel even lang zijn. =AANTALLEN.ALS(B2:B16;"Kleding";E2:E15;"Sofie") loopt vast op dat ene rijtje verschil.

Een criterium dat rechtstreeks naar een lege cel verwijst, leest Excel als 0. =AANTALLEN.ALS(C2:C16;H1) zoekt met een lege H1 dus prijzen van 0 euro, en dat geeft 0 zonder waarschuwing.

Er ontbreekt een bereik

Elk criterium hoort bij een eigen bereik. =AANTALLEN.ALS(E2:E16;"Omar";">5") werkt niet, want bij ">5" staat niet in welke kolom Excel moet kijken. Ook als twee voorwaarden over dezelfde kolom gaan, schrijf je die kolom twee keer.

Welke functies lijken op AANTALLEN.ALS?

AANTALLEN.ALS is de teller van een familie. De andere leden doen hetzelfde, maar rekenen iets anders uit, en daarom staat bij hen eerst het bereik met de getallen.

Wil je geen stuks maar bedragen, lees dan SOMMEN.ALS met voorbeelden. Het gemiddelde met een voorwaarde staat in GEMIDDELDE.ALS en GEMIDDELDEN.ALS, en elke functie met haar Engelse naam vind je op het Excel-spiekbriefje.

Wil je tellen met voorwaarden echt onder de knie krijgen, volg dan module 4 van de Excel-cursus. Je begint met AANTAL.ALS en bouwt in zes korte lessen op tot meerdere voorwaarden, en de eerste modules zijn gratis.